mirror of
https://github.com/esp-rs/esp-hal.git
synced 2025-10-02 14:44:42 +00:00
aa078f6868
* Fix ESP32-S3 direct-boot * Make ESP32-S3 direct-boot work with LLD * CHANGELOG.md entry
278 lines
9.6 KiB
Plaintext
278 lines
9.6 KiB
Plaintext
/* before memory.x to allow override */
|
|
ENTRY(ESP32Reset)
|
|
|
|
_stack_region_top = ABSOLUTE(ORIGIN(dram_seg))+LENGTH(dram_seg);
|
|
_stack_region_bottom = _stack_end;
|
|
|
|
/*
|
|
use the whole remaining memory as core-0's stack
|
|
*/
|
|
_stack_end_cpu0 = _stack_region_top;
|
|
_stack_start_cpu0 = _stack_region_bottom;
|
|
|
|
EXTERN(DefaultHandler);
|
|
|
|
INCLUDE "device.x"
|
|
|
|
/* after memory.x to allow override */
|
|
PROVIDE(__pre_init = DefaultPreInit);
|
|
PROVIDE(__zero_bss = default_mem_hook);
|
|
PROVIDE(__init_data = default_mem_hook);
|
|
PROVIDE(__post_init = default_post_init);
|
|
|
|
/*INCLUDE exception.x*/
|
|
/* exception vector for the ESP32, requiring high priority interrupts and register window support */
|
|
|
|
/* high level exception/interrupt routines, which can be override with Rust functions */
|
|
PROVIDE(__exception = __default_exception);
|
|
PROVIDE(__user_exception = __default_user_exception);
|
|
PROVIDE(__double_exception = __default_double_exception);
|
|
PROVIDE(__level_1_interrupt = __default_interrupt);
|
|
PROVIDE(__level_2_interrupt = __default_interrupt);
|
|
PROVIDE(__level_3_interrupt = __default_interrupt);
|
|
PROVIDE(__level_4_interrupt = __default_interrupt);
|
|
PROVIDE(__level_5_interrupt = __default_interrupt);
|
|
PROVIDE(__level_6_interrupt = __default_interrupt);
|
|
PROVIDE(__level_7_interrupt = __default_interrupt);
|
|
|
|
/* low level exception/interrupt, which must be overridden using naked functions */
|
|
PROVIDE(__naked_user_exception = __default_naked_exception);
|
|
PROVIDE(__naked_kernel_exception = __default_naked_exception);
|
|
PROVIDE(__naked_double_exception = __default_naked_double_exception);
|
|
PROVIDE(__naked_level_2_interrupt = __default_naked_level_2_interrupt);
|
|
PROVIDE(__naked_level_3_interrupt = __default_naked_level_3_interrupt);
|
|
PROVIDE(__naked_level_4_interrupt = __default_naked_level_4_interrupt);
|
|
PROVIDE(__naked_level_5_interrupt = __default_naked_level_5_interrupt);
|
|
PROVIDE(__naked_level_6_interrupt = __default_naked_level_6_interrupt);
|
|
PROVIDE(__naked_level_7_interrupt = __default_naked_level_7_interrupt);
|
|
|
|
/* needed to force inclusion of the vectors */
|
|
EXTERN(__default_exception);
|
|
EXTERN(__default_double_exception);
|
|
EXTERN(__default_interrupt);
|
|
|
|
/* high level CPU interrupts */
|
|
PROVIDE(Timer0 = __default_user_exception);
|
|
PROVIDE(Timer1 = __default_user_exception);
|
|
PROVIDE(Timer2 = __default_user_exception);
|
|
PROVIDE(Timer3 = __default_user_exception);
|
|
PROVIDE(Profiling = __default_user_exception);
|
|
PROVIDE(NMI = __default_user_exception);
|
|
PROVIDE(Software0 = __default_user_exception);
|
|
PROVIDE(Software1 = __default_user_exception);
|
|
|
|
/* low level exception/interrupt, which must be overridden using naked functions */
|
|
EXTERN(__default_naked_exception);
|
|
EXTERN(__default_naked_double_exception);
|
|
EXTERN(__default_naked_level_2_interrupt);
|
|
EXTERN(__default_naked_level_3_interrupt);
|
|
EXTERN(__default_naked_level_4_interrupt);
|
|
EXTERN(__default_naked_level_5_interrupt);
|
|
EXTERN(__default_naked_level_6_interrupt);
|
|
EXTERN(__default_naked_level_7_interrupt);
|
|
|
|
SECTIONS {
|
|
.pre_header (NOLOAD) : AT(0)
|
|
{
|
|
. = . + 0x400;
|
|
} > irom_seg
|
|
|
|
.header ORIGIN(ROTEXT) + 0x400 : AT(0x400)
|
|
{
|
|
LONG(0xaedb041d)
|
|
LONG(0xaedb041d)
|
|
} > irom_seg
|
|
|
|
.text ORIGIN(ROTEXT) + 0x408 : AT(0x408)
|
|
{
|
|
_stext = .;
|
|
. = ALIGN (4);
|
|
_text_start = ABSOLUTE(.);
|
|
. = ALIGN (4);
|
|
KEEP(*(.init));
|
|
*(.literal .text .literal.* .text.*)
|
|
. = ALIGN (4);
|
|
_text_end = ABSOLUTE(.);
|
|
_etext = .;
|
|
} > REGION_TEXT
|
|
_text_size = _etext - _stext;
|
|
|
|
.rodata ORIGIN(RODATA) + 0x408 + _text_size : AT(_text_size + SIZEOF(.header) + SIZEOF(.pre_header))
|
|
{
|
|
. = ALIGN (4);
|
|
_rodata_start = ABSOLUTE(.);
|
|
*(.rodata .rodata.*)
|
|
. = ALIGN (4);
|
|
_rodata_end = ABSOLUTE(.);
|
|
} > REGION_RODATA
|
|
|
|
.rwtext ORIGIN(RWTEXT) + 0x408 + _text_size + SIZEOF(.rodata) :
|
|
AT(_text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata))
|
|
{
|
|
_irwtext = ORIGIN(RODATA) + 0x408 + _text_size + SIZEOF(.rodata);
|
|
_srwtext = .;
|
|
|
|
. = ALIGN (4);
|
|
|
|
. = ALIGN(0x1000);
|
|
_init_start = ABSOLUTE(.);
|
|
KEEP(*(.WindowOverflow4.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.WindowUnderflow4.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.WindowOverflow8.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.WindowUnderflow8.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.WindowOverflow12.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.WindowUnderflow12.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.Level2InterruptVector.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.Level3InterruptVector.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.Level4InterruptVector.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.Level5InterruptVector.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.DebugExceptionVector.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.NMIExceptionVector.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.KernelExceptionVector.text));
|
|
. = ALIGN(64);
|
|
KEEP(*(.UserExceptionVector.text));
|
|
. = ALIGN(128);
|
|
KEEP(*(.DoubleExceptionVector.text));
|
|
. = ALIGN(0x400);
|
|
|
|
_init_end = ABSOLUTE(.);
|
|
|
|
*(.rwtext.literal .rwtext .rwtext.literal.* .rwtext.*)
|
|
|
|
. = ALIGN (4);
|
|
_erwtext = .;
|
|
} > REGION_RWTEXT
|
|
|
|
.data ORIGIN(RWDATA) :
|
|
AT(_text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext))
|
|
{
|
|
_data_start = ABSOLUTE(.);
|
|
. = ALIGN (4);
|
|
*(.data .data.*)
|
|
. = ALIGN (4);
|
|
_data_end = ABSOLUTE(.);
|
|
} > REGION_DATA
|
|
|
|
|
|
/* LMA of .data */
|
|
_sidata = ORIGIN(RODATA) + _text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext);
|
|
|
|
.bss (NOLOAD) : ALIGN(4)
|
|
{
|
|
_bss_start = ABSOLUTE(.);
|
|
. = ALIGN (4);
|
|
*(.bss .bss.* COMMON)
|
|
. = ALIGN (4);
|
|
_bss_end = ABSOLUTE(.);
|
|
} > REGION_BSS
|
|
|
|
.noinit (NOLOAD) : ALIGN(4)
|
|
{
|
|
. = ALIGN(4);
|
|
*(.noinit .noinit.*)
|
|
. = ALIGN (4);
|
|
} > REGION_BSS
|
|
|
|
/* must be last segment using RWDATA */
|
|
.stack_end (NOLOAD) : ALIGN(4)
|
|
{
|
|
. = ALIGN (4);
|
|
_stack_end = ABSOLUTE(.);
|
|
} > REGION_STACK
|
|
|
|
.rtc_fast.text ORIGIN(rtc_fast_seg) :
|
|
AT(_text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext) + SIZEOF(.data) + SIZEOF(.bss) + SIZEOF(.noinit))
|
|
{
|
|
. = ALIGN(4);
|
|
_rtc_fast_text_start = ABSOLUTE(.);
|
|
*(.rtc_fast.literal .rtc_fast.text .rtc_fast.literal.* .rtc_fast.text.*)
|
|
. = ALIGN(4);
|
|
_rtc_fast_text_end = ABSOLUTE(.);
|
|
} > REGION_RTC_FAST
|
|
_irtc_fast_text = ORIGIN(RODATA) + _text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext) + SIZEOF(.data) + SIZEOF(.bss) + SIZEOF(.noinit);
|
|
|
|
.rtc_fast.data ORIGIN(rtc_fast_seg) + SIZEOF(.rtc_fast.text) :
|
|
AT(_text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext) + SIZEOF(.data) + SIZEOF(.bss) + SIZEOF(.noinit) + SIZEOF(.rtc_fast.text) )
|
|
{
|
|
. = ALIGN(4);
|
|
_rtc_fast_data_start = ABSOLUTE(.);
|
|
*(.rtc_fast.data .rtc_fast.data.*)
|
|
. = ALIGN(4);
|
|
_rtc_fast_data_end = ABSOLUTE(.);
|
|
} > REGION_RTC_FAST
|
|
_irtc_fast_data = ORIGIN(RODATA) + _text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext) + SIZEOF(.data) + SIZEOF(.bss) + SIZEOF(.noinit) + SIZEOF(.rtc_fast.text);
|
|
|
|
.rtc_fast.bss ORIGIN(rtc_fast_seg) + SIZEOF(.rtc_fast.text) + SIZEOF(.rtc_fast.data) (NOLOAD) :
|
|
AT(_text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext) + SIZEOF(.data) + SIZEOF(.bss) + SIZEOF(.noinit) + SIZEOF(.rtc_fast.text) + SIZEOF(.rtc_fast.data))
|
|
{
|
|
. = ALIGN(4);
|
|
_rtc_fast_bss_start = ABSOLUTE(.);
|
|
*(.rtc_fast.bss .rtc_fast.bss.*)
|
|
. = ALIGN (4);
|
|
_rtc_fast_bss_end = ABSOLUTE(.);
|
|
} > REGION_RTC_FAST
|
|
|
|
.rtc_fast.noinit ORIGIN(rtc_fast_seg) + SIZEOF(.rtc_fast.text) + SIZEOF(.rtc_fast.data) + SIZEOF(.rtc_fast.bss) (NOLOAD) :
|
|
{
|
|
. = ALIGN(4);
|
|
*(.rtc_fast.noinit .rtc_fast.noinit.*)
|
|
. = ALIGN (4);
|
|
} > REGION_RTC_FAST
|
|
|
|
.rtc_slow.text ORIGIN(rtc_slow_seg) :
|
|
AT(_text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext) +
|
|
SIZEOF(.rtc_fast.text) + SIZEOF(.rtc_fast.data) + SIZEOF(.rtc_fast.bss))
|
|
{
|
|
. = ALIGN(4);
|
|
_rtc_slow_text_start = ABSOLUTE(.);
|
|
*(.rtc_slow.literal .rtc_slow.text .rtc_slow.literal.* .rtc_slow.text.*)
|
|
. = ALIGN(4);
|
|
_rtc_slow_text_end = ABSOLUTE(.);
|
|
} > REGION_RTC_SLOW
|
|
_irtc_slow_text = ORIGIN(RODATA) + _text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext) +
|
|
SIZEOF(.rtc_fast.text) + SIZEOF(.rtc_fast.data) + SIZEOF(.rtc_fast.bss);
|
|
|
|
.rtc_slow.data ORIGIN(rtc_slow_seg) + SIZEOF(.rtc_slow.text) :
|
|
AT(_text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext) +
|
|
SIZEOF(.rtc_fast.text) + SIZEOF(.rtc_fast.data) + SIZEOF(.rtc_fast.bss) + SIZEOF(.rtc_slow.text))
|
|
{
|
|
. = ALIGN(4);
|
|
_rtc_slow_data_start = ABSOLUTE(.);
|
|
*(.rtc_slow.data .rtc_slow.data.*)
|
|
. = ALIGN(4);
|
|
_rtc_slow_data_end = ABSOLUTE(.);
|
|
} > REGION_RTC_SLOW
|
|
_irtc_slow_data = ORIGIN(RODATA) + _text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext) +
|
|
SIZEOF(.rtc_fast.text) + SIZEOF(.rtc_fast.data) + SIZEOF(.rtc_fast.bss) + SIZEOF(.rtc_slow.text);
|
|
|
|
.rtc_slow.bss ORIGIN(rtc_slow_seg) + SIZEOF(.rtc_slow.text) + SIZEOF(.rtc_slow.data) (NOLOAD) :
|
|
AT(_text_size + SIZEOF(.header) + SIZEOF(.pre_header) + SIZEOF(.rodata) + SIZEOF(.rwtext) +
|
|
SIZEOF(.rtc_fast.text) + SIZEOF(.rtc_fast.data) + SIZEOF(.rtc_fast.bss) + SIZEOF(.rtc_slow.text) + SIZEOF(.rtc_slow.data))
|
|
{
|
|
. = ALIGN(4);
|
|
_rtc_slow_bss_start = ABSOLUTE(.);
|
|
*(.rtc_slow.bss .rtc_slow.bss.*)
|
|
. = ALIGN (4);
|
|
_rtc_slow_bss_end = ABSOLUTE(.);
|
|
} > REGION_RTC_SLOW
|
|
|
|
.rtc_slow.noinit ORIGIN(rtc_slow_seg) + SIZEOF(.rtc_slow.text) + SIZEOF(.rtc_slow.data) + SIZEOF(.rtc_slow.bss) (NOLOAD) :
|
|
{
|
|
. = ALIGN(4);
|
|
*(.rtc_slow.noinit .rtc_slow.noinit.*)
|
|
. = ALIGN (4);
|
|
} > REGION_RTC_SLOW
|
|
}
|